# HTTP server
# Copyright (C) 2023  Nguyễn Gia Phong
#
# This file if part of hybring.
#
# Hybring is free software: you can redistribute it and/or modify
# it under the terms of the GNU Affero General Public License as published by
# the Free Software Foundation, either version 3 of the License, or
# (at your option) any later version.
#
# Hybring is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU Affero General Public License for more details.
#
# You should have received a copy of the GNU Affero General Public License
# along with hybring.  If not, see <https://www.gnu.org/licenses/>.

require "http/server"
require "ini"
require "uri"

require "./sqlite"
require "./xhtml"

HTML_HEADINGS = Set{"applicants", "criteria", "joining", "members"}
MAX_CONTENT_LENGTH = 4096
MAX_NICK_LENGTH = 32
OPENNIC_TLD = Set{".bbs", ".chan", ".cyb", ".dyn", ".epic",
                  ".geek", ".gopher", ".indy", ".libre", ".neo",
                  ".null", ".o", ".oss", ".oz", ".parody", ".pirate"}

def http_error(context, status, message = nil)
  context.response.respond_with_status status, message
end

class Server
  def initialize(cfg)
    @db = Database.new cfg.db, cfg.opennic_remote, cfg.icann_remote

    @opennic_host = URI.parse(cfg.opennic_remote).host
    @opennic_page = Page.new cfg.opennic_local, cfg.opennic_remote, cfg.api, @db
    @opennic_page.write
    @icann_page = Page.new cfg.icann_local, cfg.icann_remote, cfg.api, @db
    @icann_page.write

    @server = HTTP::Server.new do |context|
      # Manually crafted request
      next http_error context, 405 if context.request.method != "POST"
      content_length = context.request.content_length
      next http_error context, 411 unless content_length
      next http_error context, 413 if content_length > MAX_CONTENT_LENGTH

      errors = {} of String => String
      params = {} of String => String
      invalid_param = false
      body = context.request.body.try &.gets_to_end || ""
      URI::Params.parse body do |key, value|
        params[key] = value
        case key
        when "nick"
          if value.size > MAX_NICK_LENGTH
            next errors["nick"] = "Must be within ${MAX_NICK_LENGTH} characters"
          end
          if /^[0-9a-z]+$/ !~ value
            next errors["nick"] = "Must be ASCII lowercase alphanumeric"
          end
        when "opennic"
          uri = URI.parse value
          next errors["opennic"] = "Must be absolute URL" unless uri.absolute?
          if uri.scheme != "http" && uri.scheme != "https"
            next errors["opennic"] = "Must be HTTP/S"
          end
          host = uri.host
          unless OPENNIC_TLD.includes? Path[host].extension
            next errors["opennic"] = "Must be under OpenNIC domain"
          end if host
        when "icann"
          uri = URI.parse value
          next errors["icann"] = "Must be absolute URL" unless uri.absolute?
          next errors["icann"] = "Must be HTTPS" unless uri.scheme == "https"
          host = uri.host # impractical to check for ICANN TLD
          if OPENNIC_TLD.includes? Path[host].extension
            next errors["icann"] = "Must not be under OpenNIC domain"
          end if host
        when "host"
        else
          break invalid_param = true
        end
      end

      # Manually crafted request
      next http_error context, 400, "Invalid Parameter" if invalid_param
      next http_error context, 400, "Missing Parameter" unless params.size == 4

      others = @db.members.each_value.chain @db.applicants.each_value
      others.each do |nick, opennic, icann|
        errors["nick"] = "Must be unique" if nick == params["nick"]
        errors["opennic"] = "Must be unique" if opennic == params["opennic"]
        errors["icann"] = "Must be unique" if icann == params["icann"]
      end
      if HTML_HEADINGS.includes? params["nick"]
        errors["nick"] = "Reserved names: #{HTML_HEADINGS.join ", "}"
      end

      if errors.empty?
        @db.add_applicant params["nick"], params["opennic"], params["icann"]
        # TODO: write feed
      else
        context.response.status_code = 400 unless errors.empty?
      end
      context.response.content_type = "application/xhtml+xml"
      if params["host"] == @opennic_host
        context.response.print @opennic_page.build errors, params
      else
        context.response.print @icann_page.build errors, params
      end
      # TODO: schedule dynamic check
    end
  end

  getter db
  getter opennic_page
  getter icann_page

  def listen(port)
    @db.update_hook ->(arg : Void*, action : Database::UpdateAction,
                       db : LibC::Char*, table : LibC::Char*, rowid : Int64) {
      return unless db == "main"
      obj = arg.as Server
      case table
      when "member"
        case action
        in .delete?
          obj.db.members.delete rowid
        in .insert?, .update?
          obj.db.update_member rowid
        end
      when "applicant"
        case action
        in .delete?
          obj.db.applicants.delete rowid
        in .insert?, .update?
          obj.db.update_applicant rowid
        end
      end
      obj.opennic_page.write
      obj.icann_page.write
    }, self.as Void*

    puts "Listening on http://#{@server.bind_tcp port}"
    @server.listen
  end
end