gnu: home: services: Add home-ssh-agent-service-type.

* gnu/home/services/ssh.scm: (<home-ssh-agent-configuration>): New type.
(home-ssh-agent-services): New procedure.
(home-ssh-agent-service-type): New variable.
* doc/guix.texi (Secure Shell): Document it.

1 files changed, 53 insertions, 1 deletions

diff --git a/gnu/home/services/ssh.scm b/gnu/home/services/ssh.scm
index d15f5ee912..205650d489 100644
--- a/gnu/home/services/ssh.scm
+++ b/gnu/home/services/ssh.scm
@@ -1,5 +1,6 @@
 ;;; GNU Guix --- Functional package management for GNU
 ;;; Copyright © 2022 Ludovic Courtès <ludo@gnu.org>
+;;; Copyright © 2023 Janneke Nieuwenhuizen <janneke@gnu.org>
 ;;;
 ;;; This file is part of GNU Guix.
 ;;;
@@ -25,9 +26,12 @@
   #:use-module (gnu services configuration)
   #:use-module (guix modules)
   #:use-module (gnu home services)
+  #:use-module (gnu home services shepherd)
   #:use-module ((gnu home services utils)
                 #:select (object->camel-case-string))
   #:autoload   (gnu packages base) (glibc-utf8-locales)
+  #:use-module (gnu packages ssh)
+  #:use-module (shepherd support)
   #:use-module (srfi srfi-1)
   #:use-module (srfi srfi-34)
   #:use-module (srfi srfi-35)
@@ -36,6 +40,7 @@
             home-openssh-configuration-authorized-keys
             home-openssh-configuration-known-hosts
             home-openssh-configuration-hosts
+            home-ssh-agent-configuration
 
             openssh-host
             openssh-host-host-name
@@ -52,7 +57,8 @@
             openssh-host-accepted-key-types
             openssh-host-extra-content
 
-            home-openssh-service-type))
+            home-openssh-service-type
+            home-ssh-agent-service-type))
 
 (define (serialize-field-name name)
   (match name
@@ -254,3 +260,49 @@ inserted after each of them."
 by providing a @file{~/.ssh/config} file, which is honored by the OpenSSH
 client,@command{ssh}, and by other tools such as @command{guix deploy}.")
    (default-value (home-openssh-configuration))))
+
+
+;;;
+;;; Ssh-agent.
+;;;
+(define-record-type* <home-ssh-agent-configuration>
+  home-ssh-agent-configuration make-home-ssh-agent-configuration
+  home-ssh-agent-configuration?
+  (openssh          home-ssh-agent-openssh          ;file-like
+                    (default openssh))
+  (socket-directory home-ssh-agent-socket-directory ;string
+                    (default (string-append %user-runtime-dir "/ssh-agent")))
+  (extra-options    home-ssh-agent-extra-options    ;list of string
+                    (default '())))
+
+(define (home-ssh-agent-services config)
+  "Return a <shepherd-service> for an ssh-agent with CONFIG."
+  (match config
+    (($ <home-ssh-agent-configuration>
+        openssh socket-directory extra-options)
+     (let* ((ssh-agent (file-append openssh "/bin/ssh-agent"))
+            (socket-file (string-append socket-directory "/socket"))
+            (command `(,ssh-agent
+                       "-D"
+                       "-a" ,socket-file
+                       ,@extra-options))
+            (log-file (string-append %user-log-dir "/ssh-agent.log")))
+       (list (shepherd-service
+              (documentation "Run the ssh-agent.")
+              (provision '(ssh-agent))
+              (start #~(lambda _
+                         (unless (file-exists? #$socket-directory)
+                           (mkdir-p #$socket-directory)
+                           (chmod #$socket-directory #o700))
+                         (fork+exec-command '#$command #:log-file #$log-file)))
+              (stop #~(make-kill-destructor))))))))
+
+(define home-ssh-agent-service-type
+  (service-type
+   (name 'home-ssh-agent)
+   (default-value (home-ssh-agent-configuration))
+   (extensions
+    (list (service-extension home-shepherd-service-type
+                             home-ssh-agent-services)))
+   (description
+    "Install and configure @command{ssh-agent} as a Shepherd service.")))