gmi.xslt


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:xhtml="http://www.w3.org/1999/xhtml">
  <xsl:output method="text" encoding="UTF-8"/>
  <xsl:variable name="root">https://loang.net</xsl:variable>
  <xsl:template match="text()">
    <xsl:value-of select="normalize-space()"/>
  </xsl:template>

  <xsl:template name="link">
    <xsl:for-each select=".//xhtml:a">
      <xsl:text>=> </xsl:text>
      <xsl:if test="substring(@href, 1, 1) = '/'">
        <xsl:value-of select="$root"/>
      </xsl:if>
      <xsl:value-of select="@href"/>
      <xsl:text> </xsl:text>
      <xsl:value-of select="."/>
      <xsl:text>&#10;</xsl:text>
    </xsl:for-each>
    <xsl:text>&#10;</xsl:text>
  </xsl:template>

  <xsl:template match="xhtml:a">
    <xsl:variable name="pre">
      <xsl:value-of select="preceding::text()[1]"/>
    </xsl:variable>
    <xsl:choose>
      <!-- consecutive anchors -->
      <xsl:when test="$pre = ' ' or $pre = '&#10;'">
        <xsl:text> </xsl:text>
      </xsl:when>
      <!-- whitespace noise -->
      <xsl:when test="normalize-space($pre) = ''"/>
      <!-- text ending with a whitespace -->
      <xsl:when test="substring($pre, string-length($pre), 1) = ' '">
        <xsl:text> </xsl:text>
      </xsl:when>
      <xsl:when test="substring($pre, string-length($pre), 1) = '&#10;'">
        <xsl:text> </xsl:text>
      </xsl:when>
    </xsl:choose>
    <xsl:value-of select="."/>
    <xsl:variable name="suf">
      <xsl:value-of select="substring(following::text()[1], 1, 1)"/>
    </xsl:variable>
    <xsl:if test="$suf = ' ' or $suf = '&#10;'">
      <xsl:text> </xsl:text>
    </xsl:if>
  </xsl:template>

  <xsl:template match="xhtml:h1">
    <xsl:text># </xsl:text>
    <xsl:value-of select="."/>
    <xsl:text>&#10;&#10;</xsl:text>
  </xsl:template>
  <xsl:template match="xhtml:h2">
    <xsl:text>## </xsl:text>
    <xsl:value-of select="."/>
    <xsl:text>&#10;&#10;</xsl:text>
  </xsl:template>
  <xsl:template match="xhtml:h3">
    <xsl:text>### </xsl:text>
    <xsl:value-of select="."/>
    <xsl:text>&#10;&#10;</xsl:text>
  </xsl:template>

  <xsl:template match="xhtml:p">
    <xsl:apply-templates select="text()|*"/>
    <xsl:text>&#10;</xsl:text>
    <xsl:call-template name="link"/>
  </xsl:template>

  <xsl:template match="xhtml:li">
    <xsl:text>* </xsl:text>
    <xsl:apply-templates select="text()|*"/>
    <xsl:text>&#10;</xsl:text>
  </xsl:template>
  <xsl:template match="xhtml:ul">
    <xsl:apply-templates select="*"/>
    <xsl:call-template name="link"/>
  </xsl:template>

  <xsl:template match="xhtml:head"/>
  <xsl:template match="xhtml:body">
    <xsl:apply-templates select="*"/>
  </xsl:template>
</xsl:stylesheet>