1 files changed, 47 insertions, 0 deletions
diff --git a/aoc/2022/08/part-one.f90 b/aoc/2022/08/part-one.f90
new file mode 100644
index 0000000..a339f48
--- /dev/null
+++ b/aoc/2022/08/part-one.f90
@@ -0,0 +1,47 @@
+PROGRAM one
+  implicit none
+  integer, parameter :: WIDTH = 99, HEIGHT = 99
+  character(WIDTH), dimension(HEIGHT) :: lines
+  integer :: i, j
+  integer, dimension(HEIGHT, WIDTH) :: grid, tmp
+  logical, dimension(HEIGHT, WIDTH) :: visible
+
+  read (*, *) lines
+  do i = 1, HEIGHT
+    do j = 1, WIDTH
+      read (lines(i)(j:j), '(I1)') grid(i, j)
+    end do
+  end do
+
+  visible(:, :) = .false.
+  visible(1, :) = .true.
+  visible(HEIGHT, :) = .true.
+  visible(:, 1) = .true.
+  visible(:, WIDTH) = .true.
+
+  tmp = grid
+  do i = 2, HEIGHT-1
+    visible(i, :) = visible(i, :) .or. tmp(i-1, :) < grid(i, :)
+    tmp(i, :) = max(tmp(i-1, :), grid(i, :))
+  end do
+
+  tmp = grid
+  do i = HEIGHT-1, 2, -1
+    visible(i, :) = visible(i, :) .or. tmp(i+1, :) < grid(i, :)
+    tmp(i, :) = max(tmp(i+1, :), grid(i, :))
+  end do
+
+  tmp = grid
+  do i = 2, WIDTH-1
+    visible(:, i) = visible(:, i) .or. tmp(:, i-1) < grid(:, i)
+    tmp(:, i) = max(tmp(:, i-1), grid(:, i))
+  end do
+
+  tmp = grid
+  do i = WIDTH-1, 2, -1
+    visible(:, i) = visible(:, i) .or. tmp(:, i+1) < grid(:, i)
+    tmp(:, i) = max(tmp(:, i+1), grid(:, i))
+  end do
+
+  print *, sum(merge(1, 0, visible))
+end program one