blob: d4a2c15547abbac88374542faee55623c39bf494 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
|
#===------------------------------------------------------------------------===#
#
# The KLEE Symbolic Virtual Machine
#
# This file is distributed under the University of Illinois Open Source
# License. See LICENSE.TXT for details.
#
#===------------------------------------------------------------------------===#
find_package(metaSMT QUIET CONFIG)
# Set the default so that if the following is true:
# * METASMT was found
# * ENABLE_SOLVER_METASMT is not already set as a cache variable
#
# then the default is set to `ON`. Otherwise set the default to `OFF`.
# A consequence of this is if we fail to detect METASMT the first time
# subsequent calls to CMake will not change the default.
if (metaSMT_FOUND)
set(ENABLE_SOLVER_METASMT_DEFAULT ON)
else()
set(ENABLE_SOLVER_METASMT_DEFAULT OFF)
endif()
option(ENABLE_SOLVER_METASMT
"Enable metaSMT solver support"
${ENABLE_SOLVER_METASMT_DEFAULT}
)
if (ENABLE_SOLVER_METASMT)
message(STATUS "metaSMT solver support enabled")
set(ENABLE_METASMT 1) # For config.h
if (NOT metaSMT_FOUND)
message(FATAL_ERROR "metaSMT not found. Try setting `-DmetaSMT_DIR=/path` where"
" `/path` is the directory containing `metaSMTConfig.cmake`")
endif()
message(STATUS "metaSMT_DIR: ${metaSMT_DIR}")
list(APPEND KLEE_SOLVER_INCLUDE_DIRS "${metaSMT_INCLUDE_DIR}" ${metaSMT_INCLUDE_DIRS})
# FIXME: We should test linking
list(APPEND KLEE_SOLVER_LIBRARIES ${metaSMT_LIBRARIES})
# Separate flags and defines from ${metaSMT_CXXFLAGS}
string(REPLACE " " ";" _metaSMT_CXXFLAGS_list "${metaSMT_CXXFLAGS}")
set(_metasmt_flags "")
set(_metasmt_defines "")
foreach (flag ${_metaSMT_CXXFLAGS_list})
if ("${flag}" MATCHES "^-D")
# This is a define
list(APPEND _metasmt_defines "${flag}")
else()
# Regular flag
list(APPEND _metasmt_flags "${flag}")
endif()
endforeach()
message(STATUS "metaSMT defines: ${_metasmt_defines}")
list(APPEND KLEE_COMPONENT_CXX_DEFINES ${_metasmt_defines})
message(STATUS "metaSMT flags: ${_metasmt_flags}")
foreach (f ${_metasmt_flags})
# Test the flag and fail if it can't be used
list(APPEND KLEE_COMPONENT_CXX_FLAGS "${f}")
endforeach()
# Check if metaSMT provides an useable backend
if (NOT metaSMT_AVAILABLE_QF_ABV_SOLVERS)
message(FATAL_ERROR "metaSMT does not provide an usable backend.")
endif()
message(STATUS "metaSMT has the following backend(s): ${metaSMT_AVAILABLE_QF_ABV_SOLVERS}.")
set(available_metasmt_backends ${metaSMT_AVAILABLE_QF_ABV_SOLVERS})
set(METASMT_DEFAULT_BACKEND "STP"
CACHE
STRING
"Default metaSMT backend. Available options ${available_metasmt_backends}")
# Provide drop down menu options in cmake-gui
set_property(CACHE METASMT_DEFAULT_BACKEND
PROPERTY STRINGS ${available_metasmt_backends})
# Check METASMT_DEFAULT_BACKEND has a valid value.
list(FIND available_metasmt_backends "${METASMT_DEFAULT_BACKEND}" _meta_smt_backend_index)
if ("${_meta_smt_backend_index}" EQUAL "-1")
message(FATAL_ERROR
"Invalid metaSMT default backend (\"${METASMT_DEFAULT_BACKEND}\").\n"
"Valid values are ${available_metasmt_backends}")
endif()
# Set appropriate defines
list(APPEND KLEE_COMPONENT_CXX_DEFINES
-DMETASMT_DEFAULT_BACKEND_IS_${METASMT_DEFAULT_BACKEND})
foreach(backend ${available_metasmt_backends})
list(APPEND KLEE_COMPONENT_CXX_DEFINES -DMETASMT_HAVE_${backend})
endforeach()
# Support newer CVC4 versions
list(APPEND KLEE_COMPONENT_CXX_DEFINES CVC4_WITHOUT_KIND_IFF)
else()
message(STATUS "metaSMT solver support disabled")
set(ENABLE_METASMT 0) # For config.h
endif()
|
