blob: c90cbda0b0cf46174ed4672000b0788149f98864 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
|
#===------------------------------------------------------------------------===#
#
# The KLEE Symbolic Virtual Machine
#
# This file is distributed under the University of Illinois Open Source
# License. See LICENSE.TXT for details.
#
#===------------------------------------------------------------------------===#
add_subdirectory(Runtest)
if ("${KLEE_RUNTIME_BUILD_TYPE}" MATCHES "Release")
set(RUNTIME_IS_RELEASE 1)
else()
set(RUNTIME_IS_RELEASE 0)
endif()
if ("${KLEE_RUNTIME_BUILD_TYPE}" MATCHES "Asserts")
set(RUNTIME_HAS_ASSERTIONS 1)
else()
set(RUNTIME_HAS_ASSERTIONS 0)
endif()
if ("${KLEE_RUNTIME_BUILD_TYPE}" MATCHES "Debug")
set(RUNTIME_HAS_DEBUG_SYMBOLS 1)
else()
set(RUNTIME_HAS_DEBUG_SYMBOLS 0)
endif()
# FIXME: This is a horrible hack that needs to die.
# Things are very inconsistent. The runtime instrinsic
# is sometimes a LLVM module or a bitcode archive.
if ("${LLVM_PACKAGE_VERSION}" VERSION_EQUAL "3.3" OR
"${LLVM_PACKAGE_VERSION}" VERSION_GREATER "3.3")
set(USE_RUNTIME_BINARY_TYPE_HACK 1)
else()
set(USE_RUNTIME_BINARY_TYPE_HACK 0)
endif()
if (ENABLE_POSIX_RUNTIME)
set(BUILD_POSIX_RUNTIME 1)
else()
set(BUILD_POSIX_RUNTIME 0)
endif()
# Configure the bitcode build system
configure_file("Makefile.cmake.bitcode.config.in"
"Makefile.cmake.bitcode.config"
@ONLY
)
# Copy over the makefiles to the build directory
configure_file("Makefile.cmake.bitcode" "Makefile.cmake.bitcode" COPYONLY)
configure_file("Makefile.cmake.bitcode.rules" "Makefile.cmake.bitcode.rules" COPYONLY)
# Makefile for root runtime directory
# Copy over makefiles for libraries
set(BITCODE_LIBRARIES "Intrinsic" "klee-libc")
if (ENABLE_POSIX_RUNTIME)
list(APPEND BITCODE_LIBRARIES "POSIX")
endif()
foreach (bl ${BITCODE_LIBRARIES})
configure_file("${bl}/Makefile.cmake.bitcode"
"${CMAKE_CURRENT_BINARY_DIR}/${bl}/Makefile.cmake.bitcode"
COPYONLY)
endforeach()
# Find GNU make
find_program(MAKE_BINARY
NAMES make gmake
)
if (NOT MAKE_BINARY)
message(STATUS "Failed to find make binary")
endif()
# Find env
find_program(ENV_BINARY
NAMES env
)
if (NOT ENV_BINARY)
message(FATAL_ERROR "Failed to find env binary")
endif()
option(KLEE_RUNTIME_ALWAYS_REBUILD "Always try to rebuild KLEE runtime" ON)
if (KLEE_RUNTIME_ALWAYS_REBUILD)
set(EXTERNAL_PROJECT_BUILD_ALWAYS_ARG 1)
else()
set(EXTERNAL_PROJECT_BUILD_ALWAYS_ARG 0)
endif()
# Build the runtime as an external project.
# We do this because CMake isn't really suitable
# for building the runtime because it can't handle
# the source file dependencies properly.
include(ExternalProject)
ExternalProject_Add(BuildKLEERuntimes
SOURCE_DIR "${CMAKE_CURRENT_BINARY_DIR}"
BINARY_DIR "${CMAKE_CURRENT_BINARY_DIR}"
CONFIGURE_COMMAND "${CMAKE_COMMAND}" -E echo "" # Dummy command
BUILD_COMMAND "${CMAKE_COMMAND}" -E echo "" # Dummy command
INSTALL_COMMAND "${CMAKE_COMMAND}" -E echo "" # Dummy command
)
# Use `ExternalProject_Add_Step` with `ALWAYS` argument instead of directly
# building in `ExternalProject_Add` with `BUILD_ALWAYS` argument due to lack of
# support for the `BUILD_ALWAYS` argument in CMake < 3.1.
ExternalProject_Add_Step(BuildKLEERuntimes RuntimeBuild
# `env` is used here to make sure `MAKEFLAGS` of KLEE's build
# is not propagated into the bitcode build system.
COMMAND ${ENV_BINARY} MAKEFLAGS="" ${MAKE_BINARY} -f Makefile.cmake.bitcode all
ALWAYS ${EXTERNAL_PROJECT_BUILD_ALWAYS_ARG}
WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}"
${EXTERNAL_PROJECT_ADD_STEP_USES_TERMINAL_ARG}
)
# Target for cleaning the bitcode build system
# FIXME: Invoke `make clean` does not invoke this target. It's also weird
# that `ExternalProject` provides no way to do a clean.
add_custom_target(clean_runtime
COMMAND ${ENV_BINARY} MAKEFLAGS="" ${MAKE_BINARY} -f Makefile.cmake.bitcode clean
WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}"
${ADD_CUSTOM_COMMAND_USES_TERMINAL_ARG}
)
###############################################################################
# Runtime install
###############################################################################
set(RUNTIME_FILES_TO_INSTALL)
# This is quite fragile and depends on knowledge in the bitcode
# build system. Hopefully it won't change very often though.
# FIXME: This hack needs to die!
if (USE_RUNTIME_BINARY_TYPE_HACK)
list(APPEND RUNTIME_FILES_TO_INSTALL
"${KLEE_RUNTIME_DIRECTORY}/kleeRuntimeIntrinsic.bc"
"${KLEE_RUNTIME_DIRECTORY}/klee-libc.bc")
else()
list(APPEND RUNTIME_FILES_TO_INSTALL
"${KLEE_RUNTIME_DIRECTORY}/libkleeRuntimeIntrinsic.bca"
"${KLEE_RUNTIME_DIRECTORY}/libklee-libc.bca")
endif()
if (ENABLE_POSIX_RUNTIME)
list(APPEND RUNTIME_FILES_TO_INSTALL
"${KLEE_RUNTIME_DIRECTORY}/libkleeRuntimePOSIX.bca")
endif()
install(FILES
${RUNTIME_FILES_TO_INSTALL}
DESTINATION "${KLEE_INSTALL_RUNTIME_DIR}")
|
