1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
|
# a solution for N=1000 to
# https://projecteuler.net/problem=14
# we use a fast local array to
# memoize small collatz numbers
#
# todo, insert sign extensions
@start
%mem =l alloc4 4000
@loop
%n =w phi @start 1, @newm %n9, @oldm %n9
%cmax =w phi @start 0, @newm %c, @oldm %cmax
%fin =w cslt %n, 1000
jnz %fin, @cloop, @end
@cloop
%n0 =w phi @loop %n, @odd %n2, @even %n3
%c0 =w phi @loop 0, @odd %c1, @even %c1
%is1 =w ceq %n0, 1
jnz %is1, @endcl, @iter0
@iter0
%ism =w cslt %n0, %n
jnz %ism, @getmemo, @iter1 # we have it in the table
@iter1
%c1 =w add %c0, 1
%p =w and %n0, 1
jnz %p, @odd, @even
@odd
%nn =w add %n0, %n0 # compute %n2 = 3 * %n0 + 1
%n1 =w add %n0, %nn
%n2 =w add %n1, 1
jmp @cloop
@even
%n3 =w div %n0, 2 # %n3 = %n0 / 2
jmp @cloop
@getmemo
%idx00 =l add %n0, %n0
%idx0 =l add %idx00, %idx00
%loc0 =l add %idx0, %mem
%cn0 =w load %loc0
%c2 =w add %c0, %cn0
@endcl
%c =w phi @getmemo %c2, @cloop %c0
%idx10 =l add %n, %n
%idx1 =l add %idx10, %idx10
%loc1 =l add %idx1, %mem
storew %c, %loc1 # memorize the result
%n9 =w add 1, %n
%big =w csle %cmax, %c
jnz %big, @newm, @oldm
@newm
jmp @loop
@oldm
jmp @loop
@end
storew %cmax, $a
ret
|
