1 files changed, 0 insertions, 121 deletions
diff --git a/src/Environment.zig b/src/Environment.zig
deleted file mode 100644
index 2fe9099..0000000
--- a/src/Environment.zig
+++ /dev/null
@@ -1,121 +0,0 @@
-//! High-level interface
-// SPDX-FileCopyrightText: 2024-2025 Nguyễn Gia Phong
-// SPDX-License-Identifier: GPL-3.0-or-later
-
-const SourceLocation = std.builtin.SourceLocation;
-const expectEqual = std.testing.expectEqual;
-const expectError = std.testing.expectError;
-const std = @import("std");
-const zeroes = std.mem.zeroes;
-
-const Value = zsanett.Value;
-const janet = @import("rename.zig").janet;
-const unwrap = zsanett.unwrap;
-const wrap = zsanett.wrap;
-const wrapFn = zsanett.wrapFn;
-const zsanett = @import("root.zig");
-
-const Environment = @This();
-table: *janet.Table,
-
-pub fn init(base: ?Environment) Environment {
-    const replacements = if (base == null) null else base.?.table;
-    return .{ .table = janet.coreEnv(replacements) };
-}
-
-/// Evaluates the Janet program given in str.
-pub fn eval(comptime T: type, str: []const u8, src: [*:0]const u8) !T {
-    var ret: Value = undefined;
-    const errflags = janet.dobytes(janet.coreEnv(null),
-                                   str.ptr, @intCast(str.len), src, &ret);
-    // Errors are already logged by Janet,
-    // among them only one is returned and not machine-readable.
-    return if (errflags == 0) unwrap(T, ret) else error.JanetError;
-}
-
-test eval {
-    zsanett.init();
-    defer zsanett.deinit();
-    try expectEqual(try eval(i32, "(+ 3 7)", @src().fn_name), 10);
-}
-
-/// Binds val to name.
-pub fn def(name: [*:0]const u8, val: anytype,
-           documentation: [*:0]const u8) !void {
-    janet.def(janet.coreEnv(null), name, try wrap(val), documentation);
-}
-
-test def {
-    const Number = struct {
-        const Number = @This();
-        n: i8,
-        pub fn nextN(self: Number) Number {
-            return Number{ .n = self.n + 1 };
-        }
-    };
-    zsanett.init();
-    defer zsanett.deinit();
-    try def("seven", Number{ .n = 7 }, "number 7 in a struct");
-    const nine = try eval(Number, "(:next-n (:next-n seven))",
-                              @src().fn_name);
-    try expectEqual(Number{ .n = 9 }, nine);
-}
-
-/// Gets value.
-pub fn resolve(T: type, name: []const u8) !T {
-    const symbol = janet.symbol(name.ptr, @intCast(name.len));
-    return try unwrap(T, janet.resolveExt(janet.coreEnv(null), symbol).value);
-}
-
-test resolve {
-    zsanett.init();
-    defer zsanett.deinit();
-    try def("pi", 3, "pi for engineers");
-    try expectEqual(try resolve(u8, "pi"), 3);
-}
-
-/// Exposes given function in Janet.
-pub fn defn(comptime fun: anytype, reg: struct {
-    prefix: ?[*:0]const u8 = null,
-    name: [*:0]const u8,
-    documentation: [*:0]const u8,
-    source: SourceLocation,
-}) !void {
-    const cfuns = [_]janet.RegExt{
-        .{
-            .name = reg.name,
-            .cfun = try wrapFn(fun),
-            .documentation = reg.documentation,
-            .source_file = reg.source.file,
-            .source_line = @bitCast(reg.source.line),
-        },
-        zeroes(janet.RegExt),
-    };
-    const env = janet.coreEnv(null);
-    if (reg.prefix) |prefix|
-        janet.cfunsExtPrefix(env, prefix, &cfuns)
-    else
-        janet.cfunsExt(env, null, &cfuns);
-}
-
-test defn {
-    zsanett.init();
-    defer zsanett.deinit();
-    try defn(struct {
-        fn add(a: i32, b: i32) i32 { return a + b; }
-    }.add, .{
-        .name = "add",
-        .documentation = "(add a b)\n\nReturn a + b.",
-        .source = @src(),
-    });
-    try expectEqual(try eval(i32, "(add 3 7)", @src().fn_name), 10);
-
-    try defn(struct {
-        fn raise() !void { return error.ThisIsFine; }
-    }.raise, .{
-        .name = "raise",
-        .documentation = "(raise)\n\nRaise an error.",
-        .source = @src(),
-    });
-    try expectError(error.JanetError, eval(void, "(raise)", @src().fn_name));
-}